如何計算生日的年齡-辦公室軟體-PHP中文網

首頁

軟體教學

辦公室軟體

如何計算生日的年齡

Christopher Nolan

Apr 17, 2025 am 09:47 AM

該教程顯示出不同的方式從Excel中生日。您將學習一些公式，以計算年齡為多年的年齡，在今天的日期或特定日期中以年，幾個月和幾天的形式獲得確切的年齡。

沒有特殊的功能可以計算Excel年齡，但是有幾種不同的方式將出生日期轉換為年齡。本教程將解釋每種方式的優點和缺點，並顯示如何在Excel中製定完美的年齡計算公式並調整以解決某些特定任務。

如何計算出excel的出生日期的年齡

在日常生活中，“您幾歲？ ”通常意味著答案，表明您還活著多少年。在Microsoft Excel中，您可以製作一個公式來計算幾個月，幾天，小時甚至分鐘的精確年齡。但是，讓我們成為傳統，並學習如何在幾年內從DOB中計算年齡。

年齡的基本Excel公式

您通常如何找出某人的年齡？只需從當前日期減去出生日期即可。這種常規的年齡公式也可以在Excel中使用。

假設出生日期在細胞B2中，那麼計算年齡的公式如下：

=(TODAY()-B2)/365

公式的第一部分（今天（） - b2）返回當前日期和出生日期之間的差異，然後將該數字除以365，以獲取年數。

該公式是明顯且易於記住的，但是有一個很小的問題。在大多數情況下，它返回一個小數號，如下面的屏幕截圖所示。

如何計算生日的年齡

要顯示完整年的數量，請使用INT功能將小數點舍入到最近的整數：

=INT((TODAY()-B2)/365)

如何計算生日的年齡

缺點：在Excel中使用此年齡公式會產生相當準確的結果，但並非完美無缺。在大多數情況下，一年中平均數量的平均天數可以正常工作，但有時會使年齡錯誤。例如，如果某人於2月29日出生，今天是2月28日，則該公式將使一個人有一天。

作為替代方案，您可以除以365.25而不是365，因為每四年級有366天。但是，這種方法也不是完美的。例如，如果您正在計算尚未過跨越一年的孩子的年齡，則除以365.25會產生錯誤的結果。

總體而言，從當前日期中減去出生日期在正常生活中效果很好，但不是Excel的理想方法。在本教程中，您將學習一些特殊功能，這些功能不管年度如何，都可以無限計算年齡。

通過年齡段功能從出生日期開始計算年齡

將DOB轉換為Excel年齡的一種更可靠的方法是使用返回一年部分的年度FRAC功能，即在兩個日期之間的整天數量。

年度FRAC函數的語法如下：

年frac（start_date，end_date，[基礎]）

前兩個論點很明顯，幾乎不需要任何其他解釋。基礎是一個可選的論點，它定義了使用的日計數基礎。

為了製定完美的年齡公式，請為年度FRAC函數提供以下值：

start_date-出生日期。
end_date-今天（）函數返回今天的日期。
基礎- 使用基礎1告訴Excel將實際天數除以每年的實際天數。

考慮到上述內容，從出生日期開始計算年齡的Excel公式如下：

年弗拉克（出生日期，今天（），1）

假設生日在細胞B2中，則該公式採用以下形狀：

=YEARFRAC(B2, TODAY(), 1)

如何計算生日的年齡

像上一個示例一樣，年度FRAC函數的結果也是十進制數字。要解決此問題，請在最後一個參數中使用0次數，因為您不需要小數點。

因此，這是計算Excel年齡的改進的年度FRAC公式：

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

如何計算生日的年齡

用日期計算Excel的年齡

將出生日期轉換為Excel年齡的另一種方法是使用日期功能：

日期（start_date，end_date，unit）

此功能可以返回各個時間單元中兩個日期之間的差異，例如年，幾個月和幾天，具體取決於您在單位參數中提供的價值：

Y-返回開始日期和結束日期之間的完整年數。
M-返回日期之間的完整月數。
D-返回兩個日期之間的天數。
YM-返回幾個月，忽略天數。
MD-返回幾天的差異，忽略了幾個月和幾年。
YD-返回幾天的差異，忽略了幾年。

由於我們的目標是計算年齡，因此我們使用“ Y”單元：

日期（出生日期，今天（），“ y”）

在此示例中，DOB在單元格B2中，您以年齡公式引用此單元格：

=DATEDIF(B2, TODAY(), "y")

如何計算生日的年齡

在這種情況下，不需要額外的捨入功能，因為具有“ Y”單元的日期公式可以計算全年數量：

如何計算生日的年齡

如何在幾年，幾個月和幾天內從生日開始年齡

正如您剛剛看到的那樣，將年齡計算為該人壽命的全年數量很容易，但這並不總是足夠的。如果您想知道確切的年齡，即某人的出生日期和當前日期之間有多少年，幾個月和幾天，請寫3個不同的日期功能：

要獲得年數： =DATEDIF(B2, TODAY(), "Y")
要獲取月數： =DATEDIF(B2, TODAY(), "YM")
要獲取天數： =DATEDIF(B2,TODAY(),"MD")

其中B2是出生日期。

然後，將上述功能加入單個公式，例如：

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

上面的公式返回以單個文本字符串連接的3個數字（年，月和天），如下屏幕截圖所示：

如何計算生日的年齡

沒什麼意義，呃？為了使結果更有意義，請與逗號分開數字並定義每個值的含義：

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

結果現在看起來好多了：

如何計算生日的年齡

該公式效果很好，但是您可以通過隱藏零值來進一步改進它。為此，添加3個如果檢查0的語句，則每個日期為一個：

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

以下屏幕截圖證明了動作中最終的Excel年齡公式 - 它在幾年，月和天中返回年齡，僅顯示非零值：

如何計算生日的年齡

提示。如果您正在尋找一個excel公式來計算年齡的年齡，請採用上述公式，然後刪除計算天數的（日期（））塊的最後一個公式。

特定公式以計算Excel年齡

在大多數情況下，上面討論的通用年齡計算公式效果很好。但是，在某些情況下，您可能需要一些非常具體的東西。當然，不可能涵蓋每種情況，但是以下示例將為您提供一些有關如何根據您的特定任務調整年齡公式的想法。

如何計算Excel中特定日期的年齡

如果您想在某個日期了解某人的年齡，請使用上面討論的日期年齡公式，但用特定日期替換2 ^nd參數中的today（）函數。

假設出生日期在B1中，以下公式將截至2020年1月1日返回年齡：

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

為了使您的年齡公式更加靈活，您可以在某個單元格中輸入日期，並在公式中引用該單元格：

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

其中B1是DOB，而B2是您要計算年齡的日期。

如何計算生日的年齡

計算一年的年齡

在未定義要計算的完整日期的情況下，此公式派上用場，您只知道一年。

假設您正在使用醫療數據庫，而您的目標是在接受最後一次完整的醫學檢查時找出患者的年齡。

假設出生日期是從第3行開始的B列，最後一次醫學檢查的年份是在C列中，則年齡計算公式如下：

=DATEDIF(B3,DATE(C3, 1, 1),"y")

由於未定義醫學檢查的確切日期，因此您將日期函數使用任意日期和月參數，例如日期（C3，1，1）。

日期函數從單元B3中提取年份，使用您提供的月份和日號（在此示例中為1-JAN），並將該日期傳遞給日期。結果，截至特定年的1月1日，您會獲得患者的年齡：

如何計算生日的年齡

找出一個人達到N年齡的日期

假設您的朋友出生於1978年3月8日。通常，您只會在該人的生日中增加50年。在Excel中，您使用日期函數進行相同的操作：

=DATE(YEAR(B2) 50, MONTH(B2), DAY(B2))

其中B2是出生日期。

您可以參考用戶可以輸入任何數年的特定單元格（在下面的屏幕截圖中）：

如何計算生日的年齡

計算不同細胞的日，月和年的年齡

當生日分為3個不同的細胞（例如B3，C3的月份，D3中的一天）時，您可以以這種方式計算年齡：

通過使用日期和日期功能來獲取出生日期： DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)
Embed the above formula into DATEDIF to calculate age from date of birth in years, months, and days: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

有關計算日期之前/之後天數的更多示例，請查看如何計算以來或直到Excel中的日期。

Excel中的年齡計算器

如果您想在Excel中擁有自己的年齡計算器，則可以使用下面解釋的一些不同的日期公式來製作一個。如果您不想重新發明輪子，則可以使用我們Excel專業人員創建的年齡計算器。

如何在Excel中創建年齡計算器

現在您知道如何在Excel中製作一個年齡公式，可以構建自定義年齡計算器，例如：

筆記。要查看嵌入式工作簿，請允許營銷餅乾。

您在上面看到的是嵌入式excel在線表，因此請隨時進入相應的單元格中的生日，您會稍後才能達到年齡。

計算器使用以下公式根據細胞A3和今天的日期根據出生日期來計算年齡。

B5中的公式計算年度，月和天的年齡： =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
B6中的公式計算幾個月的年齡： =DATEDIF($B$3,TODAY(),"m")
B7中的公式在天數中計算年齡： =DATEDIF($B$3,TODAY(),"d")

如果您在Excel表單控件方面有一定的經驗，則可以在特定日期添加一個選項以計算年齡，如以下屏幕截圖所示：

如何計算生日的年齡

為此，添加幾個選項按鈕（開發人員選項卡>插入>表單控件>選項按鈕），然後將它們鏈接到某些單元格。然後，編寫一個if/netatedif公式，以在今天的日期或用戶指定的日期中年齡。

該公式可與以下邏輯合作：

如果選擇了今天的日期選項框，則值1將出現在鏈接的單元格（i5）中，並且年齡公式根據今天的日期計算： IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
If the Specific date option button is selected AND a date is entered in cell B7, age is calculated at the specified date: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

最後，將上述功能相互嵌套，您將獲得完整的年齡計算公式（在B9中）：

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

B10和B11中的公式具有相同的邏輯。當然，它們要簡單得多，因為它們僅包含一個日期的功能，分別作為完整的月份或幾天的數量返回年齡。

要了解詳細信息，我邀請您下載此Excel年齡計算器，並研究單元格B9：B11中的公式。

下載Excel的年齡計算器

Excel的現成年齡計算器

我們的Ultimate Suite的用戶不必費心在Excel中製作自己的年齡計算器 - 只需單擊幾下：

選擇要插入年齡公式的單元格，轉到“ ablebits工具”選項卡>日期和時間組，然後單擊日期和時間嚮導按鈕。
日期和時間嚮導將開始，您直接轉到“年齡”選項卡。
在“年齡”選項卡上，您有3件事可以指定：
- 以MM/DD/YYYY格式出生的數據作為細胞參考或日期。
- 今天的日期或特定日期。
- 選擇是否計算幾天，幾個月，年或確切年齡的年齡。
單擊插入公式按鈕。

完畢！

如何計算生日的年齡

該公式會暫時插入選定的單元格中，然後雙擊填充手柄以將其複製到列下。

如何計算生日的年齡

您可能已經註意到，我們的Excel年齡計算器創建的公式比到目前為止討論的公式更為複雜，但它可以符合“ day”和“ Days”等時間單元的單數和復數單位。

如果您想擺脫“ 0天”之類的零單位，請選擇“不顯示零單元”複選框：

如何計算生日的年齡

如果您想測試這個年齡計算器，並發現Excel的60個節省時間的加載項，歡迎您在本文結尾處下載我們的Ultimate Suite的試用版。

如何突出某些年齡（在特定年齡以下）

在某些情況下，您可能不僅需要計算Excel的年齡，還需要突出顯示包含特定年齡以下年齡的細胞。

如果您的年齡計算公式返回完整年的數量，則可以根據類似的簡單公式創建常規條件格式規則：

突出顯示年齡等於或大於18：= $ c2> = 18
突出顯示18歲以下的年齡：= $ c2

其中C2是年齡柱中最高的單元格（不包括列標題）。

如何計算生日的年齡

但是，如果您的公式在數年，幾個月或幾年，幾個月和幾天中顯示年齡怎麼辦？在這種情況下，您將必鬚根據日期公式創建一個規則，該公式從年來計算出生日期。

假設出生日期是從第2行開始的B列，則公式如下：

突出顯示18歲以下的年齡（黃色）： =DATEDIF($B2, TODAY(),"Y")
突出顯示18至65歲（綠色）的年齡： =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")
突出顯示65歲以上的年齡（藍色）： =DATEDIF($B2, TODAY(),"Y")>65

要根據上述公式創建規則，請選擇要突出顯示的單元格或整個行，請轉到“ Home Tab”> “樣式組”，然後單擊條件格式>新規則>新規則… >使用公式確定要格式化的單元格。

可以在此處找到詳細的步驟：如何根據公式製定條件格式規則。

如何計算生日的年齡

這就是您在Excel中計算年齡的方式。我希望公式可以輕鬆學習，您會在工作表中嘗試一下。感謝您的閱讀，並希望下週在我們的博客上見到您！

可用下載

Excel年齡計算示例（.xlsx文件）Ultimate Suite 14天功能版本（.EXE文件）

以上是如何計算生日的年齡的詳細內容。更多資訊請關注PHP中文網其他相關文章！

陳述

本文內容由網友自願投稿，版權歸原作者所有。本站不承擔相應的法律責任。如發現涉嫌抄襲或侵權的內容，請聯絡admin@php.cn

如何將數字轉換為Excel的文本-4種快速方式May 15, 2025 am 10:10 AM

本教程展示瞭如何在Excel 2016、2013和2010中將數字轉換為文本。了解如何使用Excel的TEXT函數完成此任務，並使用數字到字符串來指定格式。學習如何使用“格式單元格…”和“文本到列”選項將數字格式更改為文本。如果你使用Excel電子表格存儲長數字或較短的數字，有一天你可能需要將它們轉換為文本。將存儲為數字的數字更改為文本可能有不同的原因。以下是你可能需要讓Excel將輸入的數字視為文本而不是數字的原因：按部分而不是整個數字進行搜索。例如，你可能需要查找所有包含50的數字，如501

如何在Excel中製作依賴（級聯）下拉列表May 15, 2025 am 09:48 AM

我們最近深入研究了Excel數據驗證的基礎知識，探討瞭如何使用逗號分隔列表，單元格範圍或命名範圍設置直接下拉列表。在今天的會話中，我們將更深入地研究此功能，重點關注此功能

如何在Excel中創建下拉列表：動態，可編輯，可搜索May 15, 2025 am 09:47 AM

本教程展示瞭如何在Excel中創建下拉列表的簡單步驟：從單元格範圍、命名範圍、Excel表格、其他工作表中創建。你還將學習如何使Excel下拉菜單動態、可編輯和可搜索。 Microsoft Excel擅長組織和分析複雜數據。其最有用的功能之一是創建下拉菜單的能力，允許用戶從預定義列表中選擇項目。下拉菜單可以使數據輸入更快、更準確和更一致。本文將向您展示幾種在Excel中創建下拉菜單的不同方法。 - Excel下拉列表 - 如何在Excel中創建下拉列表 - 從範圍 - 從命名範圍

將PDF轉換為手動或使用在線轉換器May 15, 2025 am 09:40 AM

PDF格式以其獨立於用戶軟件，硬件或操作系統顯示文檔的能力而聞名，已成為電子文件共享的標準

如何將Excel文件轉換為PDFMay 15, 2025 am 09:37 AM

本簡短教程描述了將Excel文件轉換為PDF的4種可能方法 - 使用Excel的“另存為”功能、Adobe軟件、在線Excel到PDF轉換器和桌面工具。將Excel工作表轉換為PDF通常是必要的，如果您希望其他用戶能夠查看您的數據但不能編輯它。您可能還希望將Excel電子表格轉換為PDF格式，以便用於媒體工具包、演示文稿和報告，或者創建一個所有用戶都可以打開和閱讀的文件，即使他們沒有安裝Microsoft Excel，例如在平板電腦或手機上。如今，PDF無疑是最受歡迎的文件格式之一。根據Goog

如何使用公式示例在Excel中使用SUMIF函數May 13, 2025 am 10:53 AM

This tutorial explains the Excel SUMIF function in plain English. The main focus is on real-life formula examples with all kinds of criteria including text, numbers, dates, wildcards, blanks and non-blanks. Microsoft Excel has a handful o