• 技术文章 >专题 >excel

    Excel怎么把数据合并到一个单元格

    WBOYWBOY2022-09-13 17:57:24转载546
    本篇文章给大家带来了关于excel的相关知识,其中主要介绍了关于吧多个数据合并到一个单元格的相关问题,工作中总会有一些特殊的特殊需求,最让人头疼的莫过于将符合条件的多个结果全部放到一个单元格内,下面一起来看一下,希望对大家有帮助。

    手机EXCEL下载(内含百种各行模版):点击查看

    相关学习推荐:excel教程

    工作中总会有一些特殊的特殊需求,最让人头疼的莫过于将符合条件的多个结果全部放到一个单元格内。

    举个例子,看下图。

    111.png

    A列是某公司部门名称,B列是人员姓名。

    要求将相同部门的人员姓名填入F列对应单元格,不同人名之间以逗号间隔。

    说说这道题的解法:

    首先在C2输入公式:

    =IF(A2=A1,C1&","&B2,B2)

    向下复制填充。

    222.png

    F2输入公式:

    =LOOKUP(1,0/(E2=$A$2:$A$9),C$2:C$9)

    向下复制填充,得到最终结果。

    333.png

    这个解法使用了辅助列的方式。

    C列为辅助列,是一个简单的IF函数。

    以C2的公式为例:

    =IF(A2=A1,C1&","&B2,B2)

    先判断A2和A1的值是否相等,如果相等,则返回C1&”,”&B2,如果不等,则返回B2。

    此处A2和A1的值不相等,因而公式返回B2的值”祝洪忠”。

    在公式向下复制填充的过程中,该公式得出的结果,将被公式所在单元格下方的下一个公式所使用,于是形成人名累加的效果。

    比如C3单元格公式:

    =IF(A3=A2,C2&","&B3,B3)

    A3和A2的值相等,返回真值C2&”,”&B3。

    C2为上个公式所返回的结果B2(祝洪忠),B3的值是”星光”,所以C3最后结果为”祝洪忠,星光”。

    辅助列公式输入完成后,在F列使用了一个常用的LOOKUP函数套路,得到最终结果:

    =LOOKUP(1,0/(E2=$A$2:$A$9),C$2:C$9)

    LOOKUP的这个套路,忽略错误值,总是取得最后一个符合条件的结果,我们可以总结为:

    =LOOKUP(1,0/(条件区域=指定条件),要返回的目标区域)

    该公式以0/(E2=$A$2:$A$9)构建了一个由0和错误值#DIV/0!组成的内存数组,再用永远大于0的1作为查找值,于是查找出最后一个满足部门等于E2的C列结果,即A列最后一个广告部所对应的C列值:C2。

    如果你使用的是Excel2019及以上版本,那就可以使用TEXTJOIN函数了,这个函数在最新版的WPS表格中也有。在F2单元格输入以下公式,按住SHift+Ctrl不放,按回车,OK了。

    =TEXTJOIN(",",1,IF(A$2:A$9=E2,B$2:B$9,""))

    444.png

    TEXTJOIN函数的用法为:

    =TEXTJOIN(间隔符号,是否忽略空单元格,要合并的内容)

    公式中要合并的内容为:

    IF(A$2:A$9=E2,B$2:B$9,"")

    也就是如果A$2:A$9等于E2,就返回B$2:B$9对应的内容,否则返回空文本””,结果是一个内存数组:

    {“祝洪忠”;”星光”;””;””;””;””;””;””}

    TEXTJOIN函数对IF函数得到的内存数组进行合并,第一参数指定使用间隔符号为逗号,第二参数使用1,表示忽略内存数组中的空文本。

    相关学习推荐:excel教程

    以上就是Excel怎么把数据合并到一个单元格的详细内容,更多请关注php中文网其它相关文章!

    声明:本文转载于:Excel Home,如有侵犯,请联系admin@php.cn删除
    专题推荐:Excel
    上一篇:Excel案例分享:利用函数公式来检验身份证号码的真假 下一篇:实用Excel技巧分享:跨工作表求和的四种方法
    手机EXCEL

    相关文章推荐

    • ❤️‍🔥共22门课程,总价3725元,会员免费学• 实用Excel技巧分享:神奇的“自定义格式”功能• Excel函数学习之如何快速统计工作日,看看这两个函数!• Excel数据透视表学习之按需汇总数据和工作表拆分• Excel数据透视表学习之常见疑难杂症的处理方法• Excel图表学习之如何利用控件制作条形图
    1/1

    PHP中文网