텍스트로 세포를 계산하기위한 Excel 공식 : 모든, 특정 또는 여과 된 셀

Excel에 텍스트를 포함하는 셀을 계산하는 방법?

Excel은 원래 숫자를 처리하도록 설계되었지만 오늘날 우리는 종종 텍스트를 저장하고 처리하는 데 사용합니다. 텍스트가 포함 된 워크 시트에 몇 개의 셀이 있는지 알고 싶으십니까? Microsoft Excel은이를 달성하기위한 몇 가지 기능을 제공합니다. 어떤 기능을 사용해야합니까? 상황에 따라 다릅니다. 이 튜토리얼에는 다양한 공식과 각 공식을 사용하기에 가장 좋은시기를 찾을 수 있습니다.

• 텍스트를 포함하는 통계 셀
• 빈 줄과 공백을 무시하고 텍스트를 포함하는 셀을 계산합니다.
• 특정 텍스트를 포함하는 셀의 통계
• 통계는 텍스트를 포함하는 필터링 셀

Excel에 텍스트를 포함하는 셀 수를 세는 방법

주어진 범위 내에서 텍스트 문자열 또는 문자를 포함하는 셀 수를 찾는 두 가지 기본 공식이 있습니다.

Countif 공식을 사용하여 텍스트를 포함하는 모든 셀을 계산하십시오

텍스트가 포함 된 Excel에서 셀의 수를 찾으려면 조건부 매개 변수의 별표를 사용하면 가장 쉬운 솔루션은 다음과 같습니다.

COUNTIF(*范围*, "\*") 별표 (*)는 모든 문자 시퀀스와 일치하는 와일드 카드이므로 공식은 텍스트를 포함하는 모든 셀을 계산합니다.

SumProduct 공식을 사용한 텍스트를 포함하는 통계 셀

텍스트를 포함하는 셀의 수를 얻는 또 다른 방법은 SumProduct 및 IsText 기능을 조합하여 사용하는 것입니다.

SUMPRODUCT(--ISTEXT(*范围*)) 또는

SUMPRODUCT(ISTEXT(*范围*)*1) istext 함수는 지정된 범위의 각 셀에 텍스트 문자가 포함되어 있는지 확인하고 true (텍스트 포함 셀) 및 false (기타 셀) 값의 배열을 반환합니다. 이중 단지 연산자 (-) 또는 곱셈 작업은 각각 1과 0으로 진정과 거짓을 캐스팅하여 1과 0의 배열을 생성합니다. SumProduct 함수는 배열의 모든 요소를 ​​합계하고 1의 수, 즉 텍스트를 포함하는 셀 수를 반환합니다.

이러한 공식의 작동 방식을 더 잘 이해하려면 계산되고 계산되지 않은 값을 참조하십시오.

콘텐츠 계산	수정되지 않은 콘텐츠
- 텍스트를 포함하는 셀 - 특수 문자 - 텍스트로 형식화 된 숫자 - 공백으로 간주 될 수 있지만 빈 줄 ( ""), apostrophes ( '), 공간 또는 보이지 않는 문자를 포함하는 셀	- 숫자 - 날짜 - 진실과 거짓의 논리적 값 - 실수 - 빈 셀

예를 들어, A2 : A10 범위 (숫자, 날짜, 논리적 값, 오류 및 빈 셀 제외)에 텍스트를 포함하는 셀을 계산하려면 다음 공식 중 하나를 사용할 수 있습니다.

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--ISTEXT(A2:A10))

=SUMPRODUCT(ISTEXT(A2:A10)*1)

다음 그림은 결과를 보여줍니다.

텍스트를 포함하는 공간과 빈 줄을 무시하고 셀을 포함합니다.

위에서 논의 된 공식은 텍스트 문자를 포함하는 모든 셀을 계산합니다. 그러나 경우에 따라 일부 셀은 비워 보일 수 있지만 실제로 빈 줄, 아포스트로피, 공간, 선 파단 등과 같이 인간의 눈이 볼 수없는 문자가 포함되어 있기 때문에 혼란 스러울 수 있습니다. 결과적으로, 공식으로 간주 될 수있는 셀은 공식으로 계산되어 사용자가 이유를 알아내는 것에 대해 걱정하게됩니다.

카운트에서 "거짓 양성"빈 셀을 제외하려면 Countifs 함수를 사용하고 두 번째 조건에서 "제외"문자를 사용하십시오.

예를 들어, A2 : A7 범위 ( 공간 문자를 포함하는 셀을 무시)에 텍스트를 포함하는 셀을 계산하려면 다음 공식을 사용하십시오.

=COUNTIFS(A2:A7,"*", A2:A7, " ")

대상 범위에 공식 구동 숫자가 포함 된 경우 일부 공식은 빈 문자열 ( "")을 초래할 수 있습니다. 빈 문자열이 포함 된 셀을 무시하려면 기준 1 매개 변수에서 "*"로 "*"로 대체하십시오.

=COUNTIFS(A2:A9,"*?*", A2:A9, " ")

별표로 둘러싸인 물음표는 셀에 텍스트 문자가 하나 이상 있어야 함을 나타냅니다. 빈 문자열에는 문자가 없으므로 기준을 충족하지 않으며 계산되지 않습니다. 아포스트로피 ( ')로 시작하는 빈 세포도 계산되지 않습니다.

아래 그림에는 A7의 공간, A8의 아포스트로피 및 A9 (= "")의 빈 문자열이 있습니다. 우리의 공식은이 모든 셀을 무시하고 3의 텍스트 셀 수를 반환합니다.

Excel에 특정 텍스트를 포함하는 셀을 계산하는 방법

특정 텍스트 또는 문자를 포함하는 셀의 수를 얻으려면 Countif 함수의 조건부 매개 변수에 텍스트를 제공하십시오. 다음 예는 미묘함을 설명합니다.

샘플 텍스트를 정확히 일치 시키려면 인용문에 전체 텍스트를 입력하십시오.

COUNTIF(*范围*, "*文本*") 부분적으로 일치하는 셀을 계산하려면 텍스트를 두 개의 별표 사이에 배치합니다.

COUNTIF(*范围*, "\**文本*\*") 예를 들어, A2 : A7 범위의 셀이 "바나나"라는 단어가 포함되어 있는지 확인하려면 다음 공식을 사용하십시오.

=COUNTIF(A2:A7, "bananas")

"바나나"를 포함하는 모든 셀을 내용의 일부로 계산하려면 (위치에 관계없이) 다음 공식을 사용하십시오.

=COUNTIF(A2:A7, "*bananas*")

공식을보다 쉽게 ​​사용할 수 있도록 D2와 같은 사전 정의 된 셀에 조건을 배치하고 두 번째 매개 변수에 셀 참조를 배치 할 수 있습니다.

=COUNTIF(A2:A7, D2)

D2의 입력을 기반으로 공식은 예제 텍스트와 완전히 또는 부분적으로 일치 할 수 있습니다.

• 정확히 일치하려면 바나나 와 같은 소스 테이블에 표시된 전체 단어 나 구와 동일한 단어 나 구를 입력하십시오.
• 부분 일치의 경우 * 바나나 * 와 같은 와일드 카드 문자로 둘러싸인 샘플 텍스트를 입력하십시오.

공식은 사례에 민감하지 않으므로 문자 케이스에 대해 걱정할 필요가 없습니다. 즉, * 바나나 * 도 괜찮다는 것을 의미합니다.

대안 적으로, 부분적으로 일치하는 셀을 세려면 셀 참조 및 와일드 카드 문자에 결합하십시오.

=COUNTIF(A2:A7, "*"&D2&"*")

자세한 내용은 Excel에 특정 텍스트를 포함하는 셀을 계산하는 방법을 참조하십시오.

Excel에 텍스트를 포함하는 필터링 된 셀을 계산하는 방법

Excel 필터를 사용하여 주어진 순간 동안 관련 데이터 만 표시 할 때 때로는 텍스트를 포함하는 가시 셀을 계산해야 할 수도 있습니다. 불행히도이 작업에 대한 한 번의 클릭 솔루션은 없지만 다음 예제는 단계를 안내합니다.

다음 그림과 같이 테이블이 있다고 가정하십시오. 일부 항목은 공식을 사용하여 더 큰 데이터베이스에서 추출되었으며 프로세스에서 일부 오류가 발생했습니다. 텍스트를 포함하는 셀을 계산하는 데 사용하는 Countif 공식은 모든 행을 볼 때 매우 효과적입니다.

=COUNTIF(A2:A10, "*")

이제 여러 가지 기준에 따라 여러 가지 기준에 따라 10 개 이상의 항목을 필터링하는 것과 같은 특정 기준에 따라 목록을 좁 힙니다. 질문은 - 얼마나 많은 프로젝트가 남아 있습니까?

텍스트를 포함하는 필터링 된 셀을 계산하려면 다음을 수행해야합니다.

1. 소스 테이블에서 모든 행을 보이게 만듭니다. 이렇게하려면 모든 필터와 숨겨진 숨겨진 행을 지우십시오.

2. 행이 필터링되었는지 여부를 나타내는 소계 공식을 포함하는 도우미 열을 추가하십시오. 필터링 된 셀을 처리하려면 function_num 매개 변수에 3을 사용하십시오. =SUBTOTAL(3, A2)

   모든 숨겨진 셀 (필터링되고 수동으로 숨겨진)을 식별하려면 function_num 에 103을 입력하십시오.

   =SUBTOTAL(103, A2)

   이 예에서는 다른 세포가 숨겨져있는 방법에 관계없이 텍스트를 포함하는 가시 셀을 계산하려고하므로 A2의 두 번째 공식을 입력하여 A10에 복사합니다.

   가시 셀의 경우, 공식은 1을 반환합니다. 일단 특정 행을 수동으로 필터링하거나 숨기면 공식은 0을 반환합니다. (이 0은 숨겨진 행으로 반환되기 때문에이 0을 보지 못할 것입니다. 이런 식으로 작동하는지 확인하려면 소형 공식을 포함하는 숨겨진 셀의 내용을 보이는 셀에 복사합니다 (예 : 행 2가 숨겨져 있다고 가정 할 때).

   

3. countifs 함수와 두 가지 다른 기준을 사용 하여 텍스트를 포함하는 가시 셀을 계산하기 위해 다음과 같습니다.

   • 조건 1- A2 : A10 범위의 텍스트 ( "*")를 포함하는 셀을 검색하십시오.
   • 조건 2- 가시 셀을 검출하려면 범위 D2 : D10의 검색 1.

   =COUNTIFS(A2:A10, "*", D2:D10, 1)

이제 원하는대로 데이터를 필터링 할 수 있으며 공식은 A 열 (이 경우 3)에 텍스트를 포함하는 필터링 된 셀의 수를 알려줍니다.

워크 시트에 추가 열을 삽입하지 않으려면 작업을 완료하려면 더 긴 공식이 필요합니다. 선호하는 것을 선택하십시오.

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), -- (ISTEXT(A2:A10)))

곱셈 연산자도 다음과 같습니다.

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))) * (ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10)-MIN(ROW(A2:A10)),,1)) * (ISTEXT(A2:A10)))

사용해야 할 공식은 개인 선호도에 따라 다릅니다. 결과는 어쨌든 동일합니다.

이러한 공식의 작동 방식

첫 번째 공식은 간접 함수를 사용하여 지정된 범위의 모든 셀에 대한 하위 운동에 대한 단일 참조를 "제공"합니다. 두 번째 공식은 오프셋, 행 및 최소 함수의 조합을 사용하여 동일한 목적을 달성합니다.

하위 운동 함수는 1과 0의 배열을 반환하며, 여기서 1은 가시 셀을 나타내고 0은 숨겨진 셀 (예 : 위의 보조 열)을 나타냅니다.

istext 함수는 각 셀을 A2 : A10에서 확인하고 셀에 텍스트가 포함 된 경우 TRUE를 반환합니다. 그렇지 않으면 False를 반환합니다. 이중 단지 연산자 (-)는 진실과 거짓 값을 1과 0으로 시전합니다.이 시점에서 공식은 다음과 같습니다.

=SUMPRODUCT({0;1;1;1;0;1;1;0;0}, {1;1;1;0;1;1;0;1;1})

SumProduct 함수는 먼저 두 배열에서 동일한 위치에서 요소를 곱한 다음 결과 배열을 합산합니다.

0을 곱한 결과는 0이므로, 두 배열에서 1으로 표시되는 셀 만 최종 어레이에서 1을 갖습니다.

=SUMPRODUCT({0;1;1;0;0;1;0;0;0})

위의 배열에서 1의 수는 텍스트를 포함하는 가시 셀의 수입니다.

이것은 텍스트를 포함하는 셀을 Excel에 계산하는 방법입니다. 읽어 주셔서 감사합니다. 다음 주에 우리 블로그에서 뵙기를 바랍니다!

다운로드 가능한 파일

Excel에 텍스트를 함유 한 세포를 세는 공식

위 내용은 텍스트로 세포를 계산하기위한 Excel 공식 : 모든, 특정 또는 여과 된 셀의 상세 내용입니다. 자세한 내용은 PHP 중국어 웹사이트의 기타 관련 기사를 참조하세요!