Excel 및 Google 시트의 범위에 값이 있는지 확인하십시오.

이 기사에서는 Excel 및 Google 시트에서 가장 일반적으로 사용되는 공식을 탐색하여 컬럼, 행 또는 셀 범위 내에 값이 존재하는지 확인합니다.

경험이 풍부한 사용자이든 좋아하는 스프레드 시트 프로그램에 대해 배우기 시작하든, 특정 값이 존재하는지 또는 주어진 범위에 없는지 신속하게 식별하는 방법을 알면 데이터 분석에서 많은 시간과 노력을 절약 할 수 있습니다. 이것은 대규모 데이터 세트로 작업하거나 연구를 수행 할 때 특히 유용 할 수 있습니다. Microsoft Excel 및 Google 시트에는이 작업을 수행 할 수있는 몇 가지 공식이 있습니다. 단계별 가이드를 사용하면 데이터 세트의 구조와 크기에 관계없이 스프레드 시트에 쉽게 적용 할 수 있습니다.

• Excel : 값이 범위에 있는지 확인하십시오
  • 값이 열에 존재하는 경우
  • 값이 행으로 발생하는 경우
  • 값이 범위에 나타납니다
• 범위에서 조회 값을 찾는 더 많은 공식
• Google 시트 : 값이 범위에 존재하는 경우
• 목록 - 부분 일치에 값이 있는지 확인하십시오
• 범위에 존재하는 값을 강조 표시합니다

값이 Excel의 범위에 존재하는 경우

다양한 셀에 특정 값이 존재하는지 확인하려면 일부 텍스트를 반환하고 다른 텍스트를 반환하지 않으면 IF 및 Countif 함수의 조합을 사용할 수 있습니다.

if (countif ( 범위 , 값 )> 0, "예", "아니오")

이 공식에서 Countif는 주어진 값의 발생을 범위에서 계산합니다. 카운트가 0보다 크면 if 문은 "예"를 반환합니다. 값이 범위 내에서 발견되지 않으면 Countif 함수는 0을 가져오고 출력이 "아니오"를 가져옵니다.

이 일반적인 공식은 가능한 모든 시나리오에서 잘 작동합니다.

열에 값이 존재하는지 확인하십시오

C3의 값이 A 열에 존재하는지 테스트하려면 (A3 : A20 범위에서보다 정확하게)이 공식을 사용할 수 있습니다.

=IF(COUNTIF($A$3:$A$20, C3)>0, "Yes", "No")

셀 D4 : D7에서 올바르게 복사 할 수있는 $ 부호를 사용하여 범위 참조 ($ 3 : $ A $ 20)를 잠그는주의를 기울이십시오.

값이 연속인지 확인하십시오

B5의 값이 행 B2 : i2에 나타나는지 알아 보려면 공식 이이 형식을 취합니다.

=IF(COUNTIF($B$2:$I$2, B5)>0, "Yes", "No")

값이 범위에 존재하는지 확인하십시오

2D 범위에서 특정 값이 발생하는지 확인하려면 Countif의 첫 번째 인수에 대한 해당 범위 참조를 제공하십시오. 예를 들어:

=IF(COUNTIF($A$3:$B$11, D3)>0, "Yes", "No")

범위에서 조회 값을 찾는 더 많은 공식

if countif 공식은 가장 쉽지만 특정 값이 범위에 나타나는지 확인하는 유일한 방법은 아닙니다. 다음은 몇 가지 대체 솔루션입니다.

humber와 일치

목록에서 값이 발생하는지 확인하는 또 다른 방법은 IsNumber 함수와 함께 일치하는 것입니다. 예를 들어:

=IF(ISNUMBER(MATCH(C3, $A$3:$A$20, 0)), "Yes", "No")

매치 함수는 숫자 (a3 : a20) 내에서 조회 값 (C3)의 위치를 ​​숫자로 반환합니다. 일치가없는 경우 #N/A 오류입니다. IsNumber 함수는 숫자를 true로 변환하고 오류는 false로 변환합니다. 건축을 IF로 감싸면 최종 결과로 "예"또는 "아니오"가 제공됩니다.

ISNA와 VLOOKUP

약간 더 복잡하지만 여전히 작동하는 솔루션은 IF, ISNA 및 VLOOKUP 기능을 하나의 공식으로 사용하는 것입니다.

=IF(ISNA(VLOOKUP(C3, $A$3:$A$20, 1, FALSE)), "No", "Yes")

여기서 Vlookup 함수 검색은 조회 값을 검색하는 것이 지정된 배열이며 동일한 열 (1)에서 정확한 일치 (False)를 반환합니다. 일치하지 않으면 #N/A 오류가 반환됩니다. (Excel 365 및 Excel 2021에서는 vlookup 대신 xlookup을 사용할 수 있습니다.) ISNA 함수는 #n/a 오류의 결과를 확인하고 긍정적 인 경우 true를 반환합니다. 마지막으로, IF 함수는 true (일치하지 않음)에 대해 "아니오"및 False (일치)에 대해 "예"를 반환합니다.

자세한 내용은 Excel에서 Vlookup과 함께 ISNA를 사용하는 방법을 참조하십시오.

이나와 일치

이 솔루션은 Vlookup 대신 경기를 사용하여 경기 범위를 확인하는 것을 제외하고는 이전 제품과 매우 유사합니다.

=IF(ISNA(MATCH(C3, $A$3:$A$20, 0)), "No", "Yes")

팁. 목표가 한 열에서 조회 값을 찾아 다른 열에서 일치하는 값을 반환하는 경우 기본 형식으로 vlookup 또는 xlookup 함수를 사용하는 것이 좋습니다.

Google 시트의 범위에 값이 존재하는 경우

Google 시트에서는 Excel에서 사용한 것과 정확히 동일한 공식을 사용하여 값이 범위에 존재하는지 확인할 수 있습니다.

예를 들어, D3의 값이 A3 : B11 범위에서 발생하는지 여부를 찾으려면 E4의 공식은 다음과 같습니다.

=IF(COUNTIF($A$3:$B$11, D3)>0, "Yes", "No")

샘플 스프레드 시트 에서이 튜토리얼의 끝에서 사용할 수있는 몇 가지 공식을 찾을 수 있습니다.

범위 - 부분 일치에 값이 존재하는지 확인하십시오

범위의 셀에 주어진 기판이 포함되어 있는지 확인하려면 Countif가 셀의 어느 곳에서나 찾을 수 있도록 조회 값의 양쪽에 와일드 카드 문자 (별표)를 놓습니다.

if (countif ( 범위 , " * value *")> 0, "yes", "no")

예를 들어, 벨로우 공식은 A3 : B11 범위의 셀에 "Apple"이라는 단어가 포함되어 있는지 확인합니다.

=IF(COUNTIF(A3:B11, "*apple*")>0, "Yes", "No")

하드 코드 값 대신 특정 셀을 언급하는 경우 셀 참조 전후에 별표를 연결하십시오.

=IF(COUNTIF($A$3:$B$11,"*"&D3&"*")>0, "Yes", "No")

범위에 존재하는 값을 강조 표시합니다

주어진 범위에 존재하는 값을 식별하는보다 시각적 인 방법은 Excel 조건부 형식으로 강조하는 것일 수 있습니다. 단계는 다음과 같습니다.

1. 범위에서 찾을 값이있는 셀을 선택하십시오 (우리의 경우 C3 : C7).
2. 홈 탭에서 Styles Group에서 조건부 형식> 새 규칙을 클릭하십시오.
3. 새 서식 규칙 창에서 공식을 사용하여 포맷 할 셀을 결정하십시오 .
4. 이 공식 중 하나는 이 공식이 True Box 인 형식 값 으로 입력하십시오.

   =MATCH(C3, $A$3:$A$20, 0)

   =COUNTIF($A$3:$A$20, C3)>0

   여기서 C3은 대상 값을 가진 최상위 셀이고 $ 3 : $ 20 $ 20는 확인해야 할 범위입니다.

5. 형식을 클릭하고 버튼을 클릭하고 원하는 형식을 구성하십시오.
6. 확인을 두 번 클릭하여 두 대화 창을 모두 닫습니다.

완료! 범위 (정확한 일치)에 존재하는 모든 값이 강조 표시됩니다.

부분적으로 일치하는 값을 강조하려면 아래와 같이 공식을 수정하십시오 - 조회 값 참조의 양쪽에 별표를 연결하십시오.

=MATCH("*"&C3&"*", $A$3:$A$20, 0)

=COUNTIF($A$3:$A$20, "*"&C3&"*")>0

팁. Google 스프레드 시트의 범위에서 정확한 또는 부분 일치를 강조하기 위해 Google Sheets 조건부 형식과 동일한 공식을 사용할 수 있습니다.

이제 자신감과 편안함이있는 열, 행 또는 범위에 가치가 있는지 확인하기 위해 지식과 기술이 장착되어 있습니다. 읽어 주셔서 감사합니다!

연습 통합 문서

Excel (.xlsx 파일)의 범위에 값이 존재하는지 확인 Google 시트 (온라인 시트)의 범위에 값이 존재하는지 확인하십시오.

위 내용은 Excel 및 Google 시트의 범위에 값이 있는지 확인하십시오.의 상세 내용입니다. 자세한 내용은 PHP 중국어 웹사이트의 기타 관련 기사를 참조하세요!