Excel: Comparez les chaînes dans deux cellules pour les matchs (insensible à la casse ou exacte)

Le tutoriel montre comment comparer les chaînes de texte dans Excel pour une correspondance insensible et exacte. Vous apprendrez un certain nombre de formules pour comparer deux cellules par leurs valeurs, la longueur de la chaîne ou le nombre d'occurrences d'un caractère spécifique, ainsi que de comparer plusieurs cellules.

Lorsque vous utilisez Excel pour l'analyse des données, la précision est la préoccupation la plus vitale. Des informations incorrectes conduisent à des délais manqués, aux tendances mal jugées, aux mauvaises décisions et aux revenus perdus.

Bien que les formules Excel soient toujours parfaitement vraies, leurs résultats peuvent être erronés car certaines données erronées ont pénétré dans le système. Dans ce cas, le seul remède est de vérifier les données pour la précision. Ce n'est pas grave de comparer deux cellules manuellement, mais il est presque impossible de repérer les différences entre des centaines et des milliers de chaînes de texte.

Ce tutoriel vous apprendra comment automatiser la tâche fastidieuse et sujette aux erreurs de comparaison des cellules et quelles formules sont les meilleures à utiliser dans chaque cas particulier.

• Comment comparer 2 cellules dans Excel
• Comment comparer plusieurs cellules
• Comparez une gamme de cellules à une cellule d'échantillon
• Comparez les cellules par longueur de chaîne
• Comparez les chaînes par des occurrences de caractère spécifique

Comment comparer deux cellules dans Excel

Il existe deux façons différentes de comparer les chaînes dans Excel selon que vous recherchiez une comparaison sensible à la cas ou insensible à la casse.

Formule insensible à cas pour comparer 2 cellules

Pour comparer deux cellules dans un cas ignorant Excel, utilisez une formule simple comme celle-ci:

=A1=B1

Où A1 et B1 sont les cellules que vous comparez. Le résultat de la formule sont des valeurs booléennes vraies et fausses.

Si vous souhaitez publier vos propres textes pour les correspondances et les différences, intégrez l'instruction ci-dessus dans le test logique de la fonction IF. Par exemple:

=IF(A1=B1, "Equal", "Not equal")

Comme vous le voyez dans la capture d'écran ci-dessous, les deux formules comparent les chaînes de texte, les dates et les nombres aussi bien:

Formule sensible à la cas pour comparer les chaînes dans Excel

Dans certaines situations, il peut être important non seulement de comparer les valeurs de texte de deux cellules, mais aussi de comparer le cas de caractère. La comparaison de texte sensible à la casse peut être effectuée en utilisant la fonction exacte Excel:

Exact (text1, text2)

Où Text1 et Text2 sont les deux cellules que vous comparez.

En supposant que vos cordes se trouvent dans les cellules A2 et B2, la formule se déroule comme suit:

=EXACT(A2, B2)

En conséquence, vous vous réalisez pour les chaînes de texte correspond exactement, y compris le cas de chaque personnage, faux autrement.

Si vous souhaitez que la fonction exacte fournisse d'autres résultats, intégrez-le dans une formule IF et saisissez votre propre texte pour les arguments Value_if_true et Value_if_False :

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

La capture d'écran suivante montre les résultats de la comparaison de chaînes sensibles à la cas dans Excel:

Comment comparer plusieurs cellules dans Excel

Pour comparer plus de 2 cellules d'affilée, utilisez les formules discutées dans les exemples ci-dessus en combinaison avec l'opérateur et. Les détails complets suivent ci-dessous.

Formule insensible à cas pour comparer plus de 2 cellules

Selon la façon dont vous souhaitez afficher les résultats, utilisez l'une des formules suivantes:

=AND(A2=B2, A2=C2)

ou

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

La formule et renvoie vrai si toutes les cellules contiennent la même valeur, false si une valeur est différente. La formule IF sort les étiquettes que vous tapez, " égales " et " pas égales " dans cet exemple.

Comme démontré dans la capture d'écran ci-dessous, la formule fonctionne parfaitement avec tous les types de données - texte, dates et valeurs numériques:

Formule sensible à la casse pour comparer le texte dans plusieurs cellules

Pour comparer plusieurs chaînes les uns aux autres pour voir s'ils correspondent exactement, utilisez les formules suivantes:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Ou

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Comme dans l'exemple précédent, la première formule offre des valeurs vraies et fausses, tandis que la seconde affiche vos propres textes pour les correspondances et les différences:

Comparez une gamme de cellules à une cellule d'échantillon

Les exemples suivants montrent comment vous pouvez vérifier que toutes les cellules d'une plage donnée contiennent le même texte que dans une cellule d'échantillon.

Formule insensible à cas pour comparer les cellules à un échantillon de texte

Si le cas de caractère n'a pas vraiment d'importance, vous pouvez utiliser la formule suivante pour comparer les cellules à un échantillon:

Lignes ( plage ) * colonnes ( plage ) = counttif ( plage , cellule d'échantillon )

Dans le test logique de la fonction IF, vous comparez deux nombres:

• Le nombre total de cellules dans une plage spécifiée (le nombre de lignes multiplié par le nombre de colonnes), et
• Le nombre de cellules contenant la même valeur que dans la cellule de l'échantillon (renvoyée par la fonction COUNFIF).

En supposant que l'exemple de texte est en C2 et que les chaînes à comparer se trouvent dans la plage A2: B6, la formule va comme suit:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Pour rendre les résultats plus conviviaux, c'est-à-dire sortir quelque chose comme "All Match" et "pas tous correspond" au lieu de vrai et faux, utilisez la fonction IF comme nous l'avons fait dans les exemples précédents:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Comme illustré la capture d'écran ci-dessus, la formule fait parfaitement fuites avec une gamme de chaînes de texte, mais elle peut également être utilisée pour comparer les nombres et les dates.

Formule sensible à la casse pour comparer les chaînes à un exemple de texte

Si le cas de caractère fait une différence, vous pouvez comparer les chaînes à l'exemple de texte à l'aide des formules de tableau suivantes.

If (lignes ( plage ) * colonnes ( plage ) = sum (- exact ( samptample_cell , plage )), " text_if_match ", " text_if_not correspond ")

Avec la gamme source résidant dans A2: B6 et l'échantillon de texte en C2, la formule prend la forme suivante:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Contrairement aux formules Excel régulières, les formules du tableau sont remplies en appuyant sur Ctrl Shift Entrée . Si vous êtes entré correctement, Excel enferme la formule du tableau en {Braces Curly}, comme indiqué dans la capture d'écran:

Pour identifier si une certaine valeur est présente ou absente dans une plage, veuillez consulter si une valeur existe dans une plage.

Comment comparer deux cellules par longueur de cordes

Parfois, vous pouvez vérifier si les chaînes de texte dans chaque ligne contiennent un nombre égal de caractères. La formule de cette tâche est très simple. Tout d'abord, vous obtenez la longueur de la chaîne de deux cellules en utilisant la fonction LEN, puis comparez les nombres.

En supposant que les chaînes à comparer sont dans les cellules A2 et B2, utilisez l'une des formules suivantes:

=LEN(A2)=LEN(B2)

Ou

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Comme vous le savez déjà, la première formule renvoie les valeurs booléennes vraies ou fausses, tandis que la deuxième formule publie vos propres résultats:

Comme démontré dans la capture d'écran ci-dessus, les formules fonctionnent pour les chaînes de texte ainsi que les nombres.

Conseil. Si deux chaînes apparemment égales renvoient des longueurs différentes, le problème est probablement dans les espaces de tête ou de fuite dans une ou les deux cellules. Dans ce cas, supprimez des espaces supplémentaires à l'aide de la fonction de garniture. L'explication détaillée et les exemples de formule peuvent être trouvés ici: comment couper les espaces dans Excel.

Comparez deux cellules par des occurrences d'un caractère spécifique

Ceci est le dernier exemple de notre didacticiel Excel Compare Strings, et il montre une solution pour une tâche assez spécifique. En supposant que vous avez 2 colonnes de chaînes de texte qui contiennent un caractère important pour vous. Votre objectif est de vérifier si deux cellules dans chaque ligne contiennent le même nombre d'occurrences d'un caractère donné.

Pour rendre les choses plus claires, considérez l'exemple suivant. Disons que vous avez deux listes de commandes expédiées (colonne B) et reçue (colonne C). Chaque ligne contient des commandes pour un élément spécifique, dont l'identifiant unique est inclus dans tous les ID de commande et est répertorié dans la même ligne dans la colonne A (veuillez consulter la capture d'écran ci-dessous). Vous voulez vous assurer que chaque ligne contient un nombre égal d'éléments expédiés et reçus avec cet identifiant spécifique.

Pour résoudre ce problème, écrivez une formule avec la logique suivante.

• Tout d'abord, remplacez l'identifiant unique par rien en utilisant la fonction de substitut:

  SUBSTITUTE(A1, character_to_count,"")

• Ensuite, calculez combien de fois l'identifiant unique apparaît dans chaque cellule. Pour cela, obtenez la longueur de la chaîne sans l'identifiant unique et soustrayez-le de la longueur totale de la chaîne. Cette pièce doit être écrite pour la cellule 1 et la cellule 2 individuellement, par exemple:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, "")) et LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Enfin, vous comparez ces 2 nombres en plaçant le signe d'égalité (=) entre les parties ci-dessus.

Len ( cellule 1 ) - Len (substitut ( cellule 1 , caractères_to_count , "")) = len ( cellule 2 ) - Len (substitut ( cellule 2 , caractères_to_count , ""))

Dans notre exemple, l'identifiant unique est dans A2, et les chaînes à comparer sont dans les cellules B2 et C2. Ainsi, la formule complète est la suivante:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

La formule renvoie vrai si les cellules B2 et C2 contiennent un nombre égal d'occurrences du caractère dans A2, fausse autrement. Pour rendre les résultats plus significatifs pour vos utilisateurs, vous pouvez intégrer la formule dans la fonction IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Comme vous pouvez le voir dans la capture d'écran ci-dessus, la formule fonctionne parfaitement malgré quelques complications supplémentaires:

• Le caractère à compter (identifiant unique) peut apparaître n'importe où dans une chaîne de texte.
• Les chaînes contiennent un nombre variable de caractères et différents séparateurs tels que le point-virgule, la virgule ou l'espace.

C'est ainsi que vous comparez les chaînes dans Excel. Pour examiner de plus près les formules discutées dans ce tutoriel, vous êtes invités à télécharger notre exemple de feuille ci-dessous. Je vous remercie d'avoir lu et j'espère vous voir sur notre blog la semaine prochaine!

Classeur de pratique pour télécharger

Excel - Comparez des exemples de chaînes (fichier .xlsx)

Ce qui précède est le contenu détaillé de. pour plus d'informations, suivez d'autres articles connexes sur le site Web de PHP en chinois!