So verwenden Sie IFNA -Funktion in Excel mit Beispielen

Wenn Sie viele Fehler in Ihren Arbeitsblättern erhalten, sind Sie neugierig zu wissen, ob es eine Möglichkeit gibt, stattdessen einen benutzerdefinierten Text anzuzeigen? Die IFNA -Formel ist die Lösung, die Sie benötigen.

Wenn eine Excel -Formel etwas nicht identifizieren oder finden kann, wirft sie den Fehler #n/a. Um einen solchen Fehler zu fangen und durch eine benutzerfreundliche Nachricht zu ersetzen, können Sie die IFNA-Funktion verwenden. Mit anderen Worten, #n/a ist die Art von Excels, zu sagen, dass der Wert, den Sie suchen, im referenzierten Datensatz nicht vorhanden ist. IFNA ist Ihre Art, diesen Fehler zu fangen und umzugehen.

• Was ist IFNA in Excel?
• So verwenden Sie IFNA in Excel
• So verwenden Sie IFNA mit Vlookup
• IFNA in der Array -Formel
• IFNA vs. Ifror

IFNA -Funktion in Excel

Die Excel -IFNA -Funktion ist zum Fangen und Handling #N/A -Fehler beabsichtigt. Wenn eine Formel nach #n/a bewertet, fängt IFNA diesen Fehler ab und ersetzt sie durch einen benutzerdefinierten Wert, den Sie angeben. Andernfalls gibt ein normales Ergebnis der Formel zurück.

IFNA -Syntax

Die Syntax der IFNA -Funktion lautet wie folgt:

IFNA (Wert, value_if_na)

Wo:

Wert (erforderlich) - Die Formel, der Wert oder die Referenz, um einen #n/a -Fehler zu überprüfen.

Value_if_na (erforderlich) - Der Wert zur Rückgabe, wenn ein #n/ein Fehler festgestellt wird.

Nutzungsnotizen

• Die IFNA -Funktion übernimmt nur #N/A, ohne andere Fehler zu unterdrücken.
• Wenn das Wertargument eine Array -Formel ist, gibt die IFNA ein Array von Ergebnissen zurück, eine pro Zelle, wie in diesem Beispiel gezeigt.

IFNA -Verfügbarkeit

Die IFNA -Funktion wurde in Excel 2013 eingeführt und ist in allen nachfolgenden Versionen erhältlich, einschließlich Excel 2016, Excel 2019, Excel 2021 und Microsoft 365.

In früheren Versionen können Sie #N/A -Fehler mit den Funktionen von iF und ISNA zusammenfassen.

So verwenden Sie IFNA -Funktion in Excel

Um IFNA effektiv in Excel zu verwenden, folgen Sie diesem generischen Ansatz:

1. Setzen Sie im ersten Argument ( Wert ) eine Formel, die vom Nr. N/A -Fehler beeinflusst wird.
2. Geben Sie im zweiten Argument ( value_if_na ) den Text ein, den Sie zurückgeben möchten, anstatt der Standardfehlernotation. Um eine leere Zelle zurückzugeben, wenn nichts gefunden wird, liefern Sie eine leere Zeichenfolge ('"").

Um benutzerdefinierten Text zurückzugeben, lautet die generische Formel:

IFNA ( Formel (), " benutzerdefinierter Text ")

Um eine leere Zelle zurückzugeben, lautet die generische Formel:

IFNA ( Formel (), "")

Mal sehen, wie es in einem einfachen Beispiel funktioniert. Nehmen wir in der folgenden Tabelle an, dass Sie wissen möchten, wie unter anderem eine Punktzahl eines bestimmten Schülers unter anderem rangiert. Da die Daten nach der Score -Spalte vom höchsten bis niedrigsten sortiert werden, entspricht der Rang mit der relativen Position des Schülers in der Tabelle. Um die Position zu erhalten, können Sie die Übereinstimmungsfunktion in ihrer einfachsten Form verwenden:

=MATCH(E1, A2:A10, 0)

Da der Lookup -Wert (Neal) im Lookup -Array (A2: A10) nicht verfügbar ist, tritt ein Nr. N/A -Fehler auf.

Wenn unerfahrene Benutzer auf diesen Fehler geraten, denken möglicherweise, dass mit der Formel etwas nicht stimmt, und Sie als Arbeitsmappenersteller erhalten viele Fragen. Um dies zu vermeiden, können Sie ausdrücklich angeben, dass die Formel korrekt ist. Sie kann einfach nicht den Wert finden, nach dem sie suchen sollen. Sie nisten also die Match -Formel im ersten Argument von IFNA und geben im zweiten Argument Ihren benutzerdefinierten Text "nicht gefunden" in unserem Fall "nicht gefunden":

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Anstelle der Standardfehlernotation wird Ihr eigener Text nun in einer Zelle angezeigt, wodurch Benutzer darüber informiert werden, dass der Suchwert im Datensatz nicht vorhanden ist:

So verwenden Sie IFNA mit Vlookup

Meistens tritt der Fehler #N/A in Funktionen auf, die nach so etwas wie Vlookup, Hlookup, Lookup und Übereinstimmung suchen. Die folgenden Beispiele decken einige typische Anwendungsfälle ab.

Beispiel 1. Grundlegende IFNA -Vlookup -Formel

Um #N/A -Fehler zu fangen, die auftreten, wenn Vlookup keine Übereinstimmung finden kann, überprüfen Sie das Ergebnis mit IFNA und geben Sie den zu angezeigten Wert anstelle des Fehlers an. Die übliche Praxis besteht darin, die IFNA -Funktion mit dieser Syntax um Ihre vorhandene Vlookup -Formel zu wickeln:

IFNA (vlookup (), " Ihr Text ")

Angenommen, Sie möchten in unserer Stichprobentabelle eine Punktzahl eines bestimmten Schülers (E1) abrufen. Dafür verwenden Sie diese klassische Vlookup -Formel:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Das Problem ist, dass Neal die Prüfung nicht abgelegt hat, daher ist sein Name nicht in der Liste, und offensichtlich findet Vlookup keine Übereinstimmung.

Um den Fehler zu verbergen, wickeln wir Vlookup in IFNA wie folgt ein:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Das Ergebnis sieht für den Benutzer nicht so einschüchternd aus und ist viel informativer:

Beispiel 2. IFNA vlookup, um über mehrere Blätter nachzuschauen

Die IFNA-Funktion ist auch nützlich, um die sogenannten sequenziellen oder geketteten Lookups über mehrere Blätter oder verschiedene Arbeitsmappen auszuführen. Die Idee ist, dass Sie auf diese Weise einige verschiedene IFNA -Formeln (vlookup (…)) in einen anderen nisten:

IFNA (Vlookup (…), IFNA (Vlookup (…), IFNA (Vlookup (…), "nicht gefunden"))))

Wenn ein primäres Vlookup nichts findet, wird die IFNA -Funktion das nächste Vlookup ausgeführt, bis der gewünschte Wert gefunden wird. Wenn alle Lookups fehlschlagen, gibt die Formel den angegebenen Text zurück.

Angenommen, Sie haben die Punktzahlen verschiedener Klassen in verschiedenen Blättern (benannt Klasse A , Klasse B und Klasse C ). Ihr Ziel ist es, die Punktzahl eines bestimmten Schülers zu erhalten, dessen Name in Zelle B1 in Ihrem aktuellen Arbeitsblatt eingegeben wird. Um die Aufgabe zu erfüllen, verwenden Sie diese Formel:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Die Formel sucht nacheinander nach dem angegebenen Namen in drei verschiedenen Blättern in den Orden Vlookups sind verschachtelt und bringt das erste gefundene Spiel mit:

Beispiel 3. IFNA mit Index Match

In ähnlicher Weise kann IFNA #N/A -Fehler aufnehmen, die von anderen Suchfunktionen generiert werden. Lassen Sie uns beispielsweise zusammen mit der Index -Match -Formel verwenden:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Die GIST der Formel ist die gleiche wie in allen früheren Beispielen - die Indexübereinstimmung führt eine Suche durch, und IFNA bewertet das Ergebnis und fängt einen Fehler #n/a fehler, wenn der referenzierte Wert nicht gefunden wird.

IFNA, um mehrere Ergebnisse zurückzugeben

Wenn die innere Funktion (dh die im Wert Argument angegebene Formel) mehrere Werte zurückgibt, testet die IFNA jeweils einzeln und gibt ein Array von Ergebnissen aus. Zum Beispiel:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

In Dynamic Array Excel (Microsoft 365 und Excel 2021) verschüttet eine reguläre Formel in der obersten Zelle (E2) alle Ergebnisse in den benachbarten Zellen automatisch (in Bezug auf Excel wird es als Spill -Bereich bezeichnet).

In prä-dynamischen Versionen (Excel 2019 und niedriger) kann ein ähnlicher Effekt durch Verwendung einer Multi-Zell-Array-Formel erzielt werden, die mit der Strg Shift ENTER- Verknüpfung abgeschlossen ist.

Was ist der Unterschied zwischen IFNA und ISTERROR?

Abhängig von der Grundursache des Problems kann eine Excel -Formel unterschiedliche Fehler wie #N/A, #Name, #Value, #Ref, #div/0, #Num und andere auslösen. Die ISTERROR -Funktion fängt all diese Fehler auf, während die IFNA nur auf #n/a beschränkt ist. Welches ist besser zu wählen? Das hängt von der Situation ab.

Wenn Sie einen Fehler unterdrücken möchten, verwenden Sie die ISTERROR -Funktion. Es ist besonders nützlich bei komplexen Berechnungen, wenn eine Formel mehrere Funktionen enthält, die unterschiedliche Fehler erzeugen können.

Mit Suchfunktionen sollten Sie IFNA besser verwenden, da es nur dann ein benutzerdefiniertes Ergebnis angezeigt wird, wenn ein Suchwert nicht gefunden wird und die zugrunde liegenden Probleme mit der Formel selbst nicht verbergen.

Um den Unterschied zu veranschaulichen, bringen wir unsere grundlegende IFNA -Vlookup -Formel zurück und "versehentlich" den Namen der Funktion (vlokup anstelle von vlookup).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA unterdrückt diesen Fehler nicht, sodass Sie deutlich sehen können, dass etwas mit einem der Funktionsnamen nicht stimmt:

Lassen Sie uns nun sehen, was passiert, wenn Sie IFERROR verwenden:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hmm ... es heißt, dass Olivia die Prüfung nicht abgelegt hat, was nicht wahr ist! Dies liegt daran, dass die IFERROR -Funktion den #Name fängt? Fehler und gibt stattdessen den benutzerdefinierten Text zurück. In dieser Situation gibt es nicht nur falsche Informationen zurück, sondern verdeckt auch das Problem mit der Formel.

So verwenden Sie die IFNA -Formel in Excel. Ich danke Ihnen für das Lesen und freue mich darauf, Sie nächste Woche in unserem Blog zu sehen!

Verfügbare Downloads

Beispiele für Excel IFNA -Formel (.xlsx -Datei)

Das obige ist der detaillierte Inhalt vonSo verwenden Sie IFNA -Funktion in Excel mit Beispielen. Für weitere Informationen folgen Sie bitte anderen verwandten Artikeln auf der PHP chinesischen Website!